plugins {
    id 'net.fabricmc.fabric-loom' version "${loom_version}"
    id 'maven-publish'
    id("io.freefair.lombok") version "9.0.0-rc2"
    id("com.gradleup.shadow") version '9.1.0'
}

allprojects {
    apply plugin: "io.freefair.lombok"
    apply plugin: 'java'
    version = project.mod_version
    group = project.maven_group

    base {
        archivesName = project.archives_base_name
    }

    // Lombok 1.18.40+ is required for JDK 25 (class file major version 69).
    lombok {
        version = "1.18.46"
    }

    repositories {
        // Add repositories to retrieve artifacts from in here.
        // You should only use this when depending on other mods because
        // Loom adds the essential maven repositories to download Minecraft and libraries from automatically.
        // See https://docs.gradle.org/current/userguide/declaring_repositories.html
        // for more information about repositories.
        maven {
            name = "Kalculos"
            url = "https://repo.sfclub.cc/snapshots"
        }
        mavenCentral()
    }

}

loom {
    splitEnvironmentSourceSets()

    mods {
        "justbackup" {
            sourceSet sourceSets.main
            sourceSet sourceSets.client
        }
    }

    java {
        // Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
        // if it is present.
        // If you remove this line, sources will not be generated.
        withSourcesJar()

        sourceCompatibility = JavaVersion.VERSION_25
        targetCompatibility = JavaVersion.VERSION_25
    }
    tasks.withType(JavaCompile).configureEach {
        it.options.release = 25
    }

}

dependencies {
    // To change the versions see the gradle.properties file
    // Minecraft 26.1+ is unobfuscated, so no mappings are required.
    minecraft "com.mojang:minecraft:${project.minecraft_version}"
    implementation "net.fabricmc:fabric-loader:${project.loader_version}"

    // Fabric API. This is technically optional, but you probably want it anyway.
    implementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"
    shadow project(":bundler")

    testImplementation 'org.junit.jupiter:junit-jupiter:5.13.4'
    testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
}

test {
    useJUnitPlatform()
}
configurations.implementation.extendsFrom(configurations.shadow)
shadowJar {
    configurations = [project.configurations.shadow]
    exclude("META-INF")
    dependencies {
        exclude(dependency("org.lz4:lz4-java:.*"))
        exclude(dependency("it.unimi.dsi:fastutil:.*"))
        exclude(dependency("io.netty:netty-all:.*"))
    }
    minimize()
    //relocate 'com.google', 'sfcraft.relocation.google'
}

processResources {
    inputs.property "version", project.version

    filesMatching("fabric.mod.json") {
        expand "version": inputs.properties.version
    }
}
jar {
    // Minecraft 26.1+ is unobfuscated, so there is no remapJar step; the shaded
    // jar is the distributable mod. Keep the thin jar under a separate classifier.
    archiveClassifier = 'dev'
    inputs.property "archivesName", project.base.archivesName
    from("LICENSE") {
        rename { "${it}_${inputs.properties.archivesName}" }
    }
}

shadowJar {
    archiveClassifier = ''
}

assemble.dependsOn shadowJar

// configure the maven publication
publishing {
    publications {
        create("mavenJava", MavenPublication) {
            artifactId = project.archives_base_name
            from components.java
        }
    }

    // See https://docs.gradle.org/current/userguide/publishing_maven.html for information on how to set up publishing.
    repositories {
        // Add repositories to publish to here.
        // Notice: This block does NOT have the same function as the block in the top level.
        // The repositories here will be used for publishing your artifact, not for
        // retrieving dependencies.
    }
}